home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
sh4x
/
sh45a.d64
/
listing 13
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
3KB
|
67 lines
10 REM * SPRITE BEISPIEL 2 *
20 REM NOCH EINMAL DER HEISSLUFTBALLON
30 VIC=13*4096:REM HIER BEGINNEN DIE VIC-REGISTER
35 POKE VIC+21,63:REM EINSCHALTEN SPRITE 0 BIS 5
36 POKE VIC+33,14:REM HINTERGRUNDFARBE HELLBLAU
37 POKE VIC+23,3:REM SPRITE 0 UND 1 IN Y VERDOPPELN
38 POKE VIC+29,3:REM UND IN X
40 POKE 2040,192:REM SPRITEZEIGER 0 AUF BLOCK 192
50 POKE 2041,193:REM SPRITEYEIGER 1
60 POKE 2042,192:REM SPRITEZEIGER 2
70 POKE 2043,193:REM SPRITEZEIGER 3
80 POKE 2044,192:REM SPRITEZEIGER 4
90 POKE 2045,193:REM SPRITEZEIGER 5
100 POKE VIC+4,30:REM X-POSITION SPRITE 2
110 POKE VIC+5,58:REM Y-POSITION SPRITE 2
120 POKE VIC+6,65:REM X-POSITION SPRITE 3
130 POKE VIC+7,58:REM Y-POSITION SPRITE 3
140 POKE VIC+8,100:REM X-POSITION SPRITE 4
150 POKE VIC+9,58:REM Y-POSITION SPRITE 4
160 POKE VIC+10,100:REM X-POSITION SPRITE 5
170 POKE VIC+11,58:REM Y-POSITION SPRITE 5
175 PRINT"[147]"TAB(15)"DIES SIND 2 HIRES-SPRITES";
176 PRINTTAB(55)"EINER UEBER DEM ANDEREN"
180 POKE VIC,100:REM X-POSITION SPRITE 0
190 POKE VIC+1,100:REM UND Y-POSITION
200 POKE VIC+2,100:REM X-POSITION SPRITE 1
210 POKE VIC+3,100:REM Y-POSITION SPRITE 1
220 POKE VIC+39,1:REM FARBE SPRITE 0
230 POKE VIC+41,1:REM FARBE SPRITE 2
240 POKE VIC+43,1:REM FARBE SPRITE 4
250 POKE VIC+40,6:REM FARBE SPRITE 1
260 POKE VIC+42,6:REM FARBE SPRITE 3
270 POKE VIC+44,6:REM FARBE SPRITE 5
280 FOR X=192 TO 193:REM SPRITEDEFINITIONEN
290 FOR Y=0 TO 63:REM BYTEZAEHLER
300 READ A:REM SPRITEDATEN LESEN
310 POKE X*64+Y,A:REM UND EINTRAGEN
320 NEXT Y,X
330 DX=1:DY=1
340 X=PEEK(VIC):REM X-POSITION SPRITE 0 PRUEFEN
350 Y=PEEK(VIC+1):REM Y-POSITION TESTEN
360 IF Y=50 OR Y=200 THEN DY=-DY:REM BEI RANDPOSITION DY UMKEHREN
380 IF X=24 AND (PEEK(VIC+16)AND 1)=0 THEN DX=-DX:REM WENN SPRITE
390 REM AM LINKEN RAND (X<24 UND MSB=0) DANN DX UMKEHREN
400 IF X=40 AND (PEEK(VIC+16)AND 1)=1 THEN DX=-DX:REM WENN SPRITE
410 REM AM RECHTEN RAND (X=40 UND MSB=1) DANN DX UMDREHEN
420 IF X=255 AND DX=1 THEN X=-1:SIDE=3
430 REM UMSCHALTEN AUF ANDERE BILDSCHIRMSEITE
440 IF X=0 AND DX=-1 THEN X=256:SIDE=0
450 REM UMSCHALTEN AUF ANDERE BILDSCHIRMSEITE
460 X=X+DX:REM ADDIEREN VON DX ZU X
470 X=X AND 255:REM SICHERSTELLEN DASS X IM ERLAUBTEN BEREICH
480 Y=Y+DY
485 POKE VIC+16,SIDE
490 POKE VIC,X:REM NEUE X-POSITION SPRITE 0
500 POKE VIC+2,X:REM NEUER X-WERT SPRITE 1
510 POKE VIC+1,Y:REM NEUER Y-WERT
520 POKE VIC+3,Y:REM NEUER Y-WERT SPRITE 1
530 GOTO 340
600 REM ***** SPRITE DATEN *****
610 DATA 0,255,0,3,153,192,7,24,224,7,56,224,14,126,112,14,126,112,14,126,112
620 DATA 6,126,96,7,56,224,7,56,224,1,56,128,0,153,0,0,90,0,0,56,0
630 DATA 0,56,0,0,0,0,0,0,0,0,126,0,0,42,0,0,84,0,0,40,0,0
640 DATA 0,0,0,0,102,0,0,231,0,0,195,0,1,129,128,1,129,128,1,129,128
650 DATA 1,129,128,0,195,0,0,195,0,4,195,32,2,102,64,2,36,64,1,0,128
660 DATA 1,0,128,0,153,0,0,153,0,0,0,0,0,84,0,0,42,0,0,20,0,0